#!/bin/tcsh
#
# tcsh の設定ファイル
#
# written by NegI <negi@KU3G.org>
# Lastupdate: Fri Apr 21 04:13:01 2000.
# $Id: .cshrc,v 1.1 2000/04/18 03:26:38 negi Exp negi $

# パスの設定
set local=(/usr/local/{bin,X11/bin,bin/mh,bin/netpbm,games})
set sbin=(/sbin /usr/sbin/ /usr/local/sbin)
set java=(/usr/local/jdk1.2/bin)
switch (`uname`)
    case Linux:
    set path=(~/bin /bin /usr/bin $local $sbin $java\
	/usr/{X11R6,openwin}/bin .)
    breaksw
    default:
    set path=(~/bin /bin /usr/bin $local \
	/usr/X11R6/bin)
endsw

if ($?prompt == 0) exit # 以下はインタラクティブシェルのみに必要

stty sane crt erase ^H stop ^-
# core は吐かせない
#limit coredumpsize 0

# シェル変数の設定
set ignoreeof
set history=100
set savehist=$history
set cdpath=( ~/ ~/work ~/souko ~/work/jikken /pub/fsw /pub/lib )
set fignore=(.o .aux .out \~)

# ホスト名一覧
set hosts=`awk '/^[1-9].*/ {print $3'} /etc/hosts`
set ftphosts=`awk -F , '/2/ {print $1}' $HOME/.ncftp/bookmarks`
set xhosts=(clotho:0 lachesis:0 calpain:0 atropos:0)
set ssh_hosts=(bamboo ns leo prelude)

# alias の設定
alias bakrm	'rm *~'
alias dc	'cd'
alias down	'echo down >/var/run/diald.ctl'
alias dgrep	'find . -name '\!:2' -print | xargs grep \!:1'
alias dir	'ls -ls'
#alias emacs	'gnuclient'
#alias mule	'gnuclient'
alias ftp	'ncftp'
alias h		'history 25'
alias k		'kterm -e screen'
alias ll	'\ls -algF --color=auto'
alias ls	'ls --color=auto -F'
alias lame	'lame -p -h'
alias mem	'ps aux | sort +5n'
alias mkisofs	'mkisofs -a -l -r -J -D -L -m .listing -m .mirror'
alias cdrecord	'cdrecord dev=0,2,0 speed=4 -v -eject'
alias nw	'\emacs -nw'
alias po	'popd'
alias ps	'ps x'
alias psn	'\ps ax | grep -v grep | grep \!$'
alias pu	'pushd'
alias play	'esdplay'
alias rogue	'rogue /usr/local/games/mesg'
alias su	'su -m'
alias untar	'tar zxvf'
alias xsetimage 'xv -root -quit'
alias whois	'whois -h whois.nic.ad.jp'
alias du	'du -h'
alias df	'df -h'
alias ulame	'lame --lowpass 15 --lowpass-width 0'
alias vi	'jvim'
alias smbmount	'smbmount \!* -o fmask=644'
alias rpm	'rpm --target=i586'
alias su	'sudo su -m'

#if ($?DISPLAY && ! $?EMACS) then
# alias cwdcmd 'echo -n "]2;${HOST}[$cwd]]1;${HOST}"'
# cd .
# alias rsh	'rsh \!* ; cd .'
# alias ssh	 'ssh \!* ; cd .'
# alias rlogin	'rlogin \!* ; cd .'
# alias slogin	 'slogin \!* ; cd .'
# alias telnet	'telnet \!* ; cd .'
#endif

if ($?DISPLAY) then # Xクライアントはバックグラウンドで実行
    alias ghostview	'ghostview \!* &'
    alias gimp		'gimp \!* &'
    alias kterm		'kterm \!* &'
    # alias mule	'emacs \!* &'
    # alias emacs	'emacs \!* &'
    alias gqmpeg	'gqmpeg \!* &'
    alias nscape	'netscape \!* &'
    alias replay	'replay \!* &'
    alias tgif		'tgif \!* &'
    # alias timidity	'timidity \!* &'
    alias xanim		'xanim +f \!* &'
    alias xdvi		'xdvi \!* &'
    alias xless		'kterm -e less \!* &'
    alias xpaint	'xpaint -nowarn \!* &'
    alias xplaymidi	'xplaymidi \!* &'
    alias xterm		'xterm \!* &'
    alias xnetload	'xnetload -if ppp0 \!* &'
    alias xv		'xv \!* &'
    alias xdic		'xdic -f /usr/dict/honmon -G /usr/dict/gai16f00 -H /usr/dict/gai16h00 &'
    alias x11amp	'x11amp \!* &'
    alias mtv		'mtv \!* &'
    alias dctrl		'dctrl -fifo /var/run/diald.ctl -toolbar \!* &'
endif

set user=`/usr/bin/whoami`
unset autologout
if ($uid != 0 ) then
    set prompt='%m[%~]%L% '
else
    set prompt='root[%~]#%L '
endif
set symlinks=expand
set rmstar
set histdup=erase
set matchbeep=nomatch
set autocorrect
set autolist ambiguous
set dspkanji=euc
set dspleft=3
set color

alias dirs	'dirs -v'

# emacs のシェルモードで行末に "^M" が表示されるのを防ぐ
if ($?EMACS) then
    unset edit
    stty nl
endif

# キーバインドの設定
bindkey '^R' i-search-back # C-r でヒストリのインクリメンタルサーチ
bindkey '^?' delete-char   # Del で文字を消す

# 補間機能の設定
set noglob
complete '-mtv*'	'p/0/(mtv)/'
complete '-xau*'	'p/0/(xaudio)/'
complete '-mxa*'	'p/0/(mxaudio)/'
complete '-s'		'p/0/(screen)/'
complete '-fet'		'p/0/(fetchmail)/'
complete '-rep'		'p/0/(replay)/'
complete dd	c/if=/f/ c/of=/f/
complete cdcd	'p/1/(play stop open close)/'
complete exec	n/*/c/
complete kill	'c/-/S/' 'c/%/j/'
complete man	n/*/c/
complete which	n/*/c/
complete make	'p/1/(all clean install config)/'
complete psn	n/*/c/
complete rcp 'c%*@*:%`set q=$:-0;set q="$q:s/@/ /";set q="$q:s/:/\
		/";set q=($q " ");rsh $q[2] -l $q[1] ls -dp $q[3]\*`%'\
		'c%*:%`set q=$:-0;set q="$q:s/:/ /";set q=($q " "); \
		rsh $q[1] ls -dp $q[2]\*`%' 'c%*@%$hosts%:' \
		'C@[./$~]*@f@'	'n/*/$hosts/:'
complete rsh		'p/1/$hosts/'
complete ssh		'p/1/$ssh_hosts/'
complete '-rl*'		'p/0/(rlogin)/'
complete rlogin		'p/1/$hosts/'
complete slogin		'p/1/$ssh_hosts/'
complete ftp		'p/1/$ftphosts/'
complete {un}setenv	p/1/e/
complete screen		n/*/c/
complete xanim		n/*/f:*.{mov,MOV,avi,AVI}/
complete mpg123		n/*/f:*.{mp3,mp2,MP3,MP2}/
complete zcat		n/*/f:*.{gz,GZ,Z,z}/
complete {*tex}		p/1/f:*.{tex,texi,texinfo}/
complete {xplaymidi,playmidi}	n/*/f:*.{mid,MID}/
complete {mp,timi}	n/*/f:*.{mid,MID,rcp,RCP}/
complete {xdvi,dvips}	n/*/f:*.dvi/
complete xv	'c/-/(root quit display)/'\
		'n/-display/$xhosts/'
complete xsetimage	'c/-/(root quit display)/'\
			'n/-display/$xhosts/'
complete {ghostview}	p/1/f:*.{ps,eps,PS,EPS}/
complete {gv}		p/1/f:*.{ps,eps,PS,EPS}/
complete {cd,popd,pushd,po,pu}	p/1/d/
complete {gogo,lame}	p/1/f:*.wav/
complete rpm	'c/--/(short-circuit rebuild)/'\
		'c/-/(ivh Uvh)/'\
		'n/--rebuild/f:*.src.rpm/'\
		'n/-i/f:*.rpm/' \
		'n/-U/f:*86.rpm/'\
		'n/-e/`rpm -qa`'/
complete {gtar,tar}	p/1/"(cvf tvf xvf cvfz zxvf)"/\
			p/2/f:*.{tar,tar.{gz,Z},taz,tgz}/\
			c/[ctx]vf*/"(z O p B)"/\
			n/*/f/
unset noglob

# カラー ls の設定
eval `dircolors -c ~/.dir_colors`
if ($?EMACS) then
    alias ls	'ls --color=no -F'
endif

#ディスプレイの設定
if ( $?DISPLAY == 0 && $?REMOTEHOST ) then
    setenv DISPLAY ${REMOTEHOST}:0.0
endif